【Outlook VBA】仕分けをワイルドカード付きのタイトルで行う

Option Explicit
Private Sub Application_NewMailEx(ByVal EntryIDCollection As String)
    
    ''【test】*というタイトルのメールをtestフォルダに仕分ける
    MoveMail EntryIDCollection, "test", "【test】*"
End Sub
Sub MoveMail(entryID As String, strFldrName As String, titleWithWild As String, Optional strAddress = "")
    '''strFldrName：移動させるフォルダ名
    '''titleWithWild：ワイルドカード付きのタイトル
    
    Dim myNameSpace As NameSpace
    Set myNameSpace = GetNamespace("MAPI")
    
    ''移動先のフォルダ取得
    On Error GoTo NoFldr
    Dim myInbox As Outlook.Folder
    Set myInbox = myNameSpace.GetDefaultFolder(olFolderInbox).Folders.Item(strFldrName)
    On Error GoTo 0
    
    Dim itemMail As Outlook.MailItem
    Set itemMail = myNameSpace.GetItemFromID(entryID)
    
    ''タイトルがマッチしなければ早期Rtn
    If Not (itemMail.Subject Like titleWithWild) Then Exit Sub
    
    If strAddress = "" Or strAddress = GetSenderEmailAddress(itemMail) Then
        itemMail.Move myInbox
    End If
    
NoFldr:
End Sub
Private Function GetSenderEmailAddress(ByRef oItem As MailItem) As String
    '''送信者のメールアドレスを取得する
    '''「アルパカのメモ」様より引用
    '''https://vicugna-pacos.github.io/vba/outlook/sender-email-address/
    Dim PR_SMTP_ADDRESS  As String
    Dim oSender As AddressEntry
    Dim oExUser As ExchangeUser
    
    
    PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
    
    ' Exchange 以外
    If oItem.SenderEmailType <> "EX" Then
        GetSenderEmailAddress = oItem.SenderEmailAddress
        Exit Function
    End If
    
    Set oSender = oItem.Sender
    
    If oSender.AddressEntryUserType = olExchangeUserAddressEntry _
        Or oSender.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
        
        Set oExUser = oSender.GetExchangeUser
        GetSenderEmailAddress = oExUser.PrimarySmtpAddress
        Exit Function
    End If
    
    GetSenderEmailAddress = oSender.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
End Function

Private Sub Application_NewMailEx(ByVal EntryIDCollection As String)
    
    ''【test】*というタイトルのメールをtestフォルダに仕分ける
    MoveMail EntryIDCollection, "test", "【test】*"
End Sub

    MoveMail EntryIDCollection, "test", "【test】*", "xxx@xxx"