【VBA】ExcelからOutlook会議を設定するプログラム

Sub MakeMTG()
    '会議アイテムを作成⇒表示
    
    '対象行
    Dim itemRow As Long: itemRow = 2
    
    Dim olApp As Object
    Set olApp = CreateObject("Outlook.Application")
    Dim olAppItem As Object
    Set olAppItem = olApp.CreateItem(1) 'olAppointmentItem
    With olAppItem
        .MeetingStatus = 1 '会議アイテム（olMeeting）
        .Subject = Cells(itemRow, 1) '会議名
        
        '時間設定（エラーが発生する場合は終了）
        On Error GoTo TimeError
        .Start = Cells(itemRow, 2)
        .End = Cells(itemRow, 3)
        On Error GoTo 0
        
        .Location = Cells(itemRow, 4) '場所
        .ReminderSet = True 'アラームをセット
        .ReminderMinutesBeforeStart = 1440 '1日前にアラーム
    End With
    
    '必須出席者
    Call AddRcpReq(olAppItem, Cells(itemRow, 5))
    Call AddRcpReq(olAppItem, Cells(itemRow, 6))
    Call AddRcpReq(olAppItem, Cells(itemRow, 7))
    Call AddRcpReq(olAppItem, Cells(itemRow, 8))
    
    olAppItem.Display '会議アイテムを表示
    Set olApp = Nothing: Set olAppItem = Nothing
    Exit Sub
    
TimeError:
    MsgBox "開始or終了時刻の値を修正してください"
    
End Sub
Private Sub AddRcpReq(olAppItem As Object, mailAddress As String)
    'mailAddressを必須出席者に追加
    'mailAddressが""の場合は追加しない
    
    If mailAddress = "" Then Exit Sub
    
    With olAppItem.Recipients.Add(mailAddress)
        .Type = 1 '必須出席者（olRequired）
    End With
End Sub

    Dim itemRow As Long: itemRow = 2