【VBA】画像ファイルをセル範囲に合わせて拡大縮小するマクロ

Sub ImportPicSelection()
'外部から画像ファイルをインポートし、選択範囲のサイズに合わせて貼付ける

    Const MARGIN = 0.95 '余白調整用
    
    'セル以外を選択している場合はExit
    If Not TypeName(Selection) = "Range" Then Exit Sub
    
    '画像ファイルの選択
    Dim filePath As String
    filePath = Application.GetOpenFilename( _
        filefilter:="Pictures (*.png; *.gif; *.jpg; *.bmp; *.tif),*.png; *.gif; *.jpg; *.bmp; *.tif", _
        Title:="画像選択ダイアログ", _
        MultiSelect:=False)
    
    '画像選択されない場合はExit
    If filePath = "False" Then Exit Sub
    
    '画像ファイルの取込み
    With ActiveSheet.Shapes.AddPicture( _
        Filename:=filePath, _
        linktofile:=False, _
        savewithdocument:=True, _
        Left:=Selection.Left, _
        Top:=Selection.Top, _
        Width:=0, _
        Height:=0)
        
        '一旦元のサイズに戻す
        .ScaleHeight 1, msoTrue
        .ScaleWidth 1, msoTrue
        
        'サイズ調整（Selection内に収める）
        Dim dblScal As Double
        If Selection.Width / .Width < Selection.Height / .Height Then
            dblScal = WorksheetFunction.RoundDown(Selection.Width / .Width, 2) * MARGIN
        Else
            dblScal = WorksheetFunction.RoundDown(Selection.Height / .Height, 2) * MARGIN
        End If
        .ScaleHeight dblScal, msoFalse
        .ScaleWidth dblScal, msoFalse
        
        'Selectionの中心に配置
        .Left = .Left + (Selection.Width - .Width) / 2
        .Top = .Top + (Selection.Height - .Height) / 2
        
    End With
End Sub